eac-post.bat

@ECHO OFF
CLS

REM ===================
REM  Parameter mapping
REM ===================
REM  %o  %s  %d  "%a"  "%g"
REM  %1  %2  %3   %4    %5

ECHO EAC-POST.BAT
ECHO ============
ECHO.
ECHO Original    (o) : %1
ECHO Source      (s) : %2
ECHO Destination (d) : %3
ECHO CD Artist   (a) : %4
ECHO CD Title    (g) : %5
ECHO.
ECHO MAC.EXE         : %pathToMac%
ECHO TAG.EXE         : %pathToTag%
ECHO PAR2.EXE        : %pathToPar2%
ECHO.
ECHO Cuesheet        : "%~dp3%~n1%~x3.cue"

REM Ensure final APE file has been created... 
:ApeFileCheck
IF NOT EXIST "%~dp3%~n1%~x3" GOTO WaitForApeFile
ECHO.
ECHO "%~dp3%~n1%~x3" exists.

ECHO.
ECHO CALLING TAG USING THE FOLLOWING COMMAND:
ECHO %pathToTag% --ape2 --artist %4 --album %5 -f "CUESHEET=%~dp3%~n1%~x3.cue" "%~dp3%~n1%~x3"
ECHO ________________________________________________________________________
ECHO.
REM =============================================
REM  Add cuesheet using TAG.EXE
REM =============================================
%pathToTag% --ape2 --artist %4 --album %5 -f "CUESHEET=%~dp3%~n1%~x3.cue" "%~dp3%~n1%~x3"

ECHO.
ECHO CALLING PAR2 USING THE FOLLOWING COMMAND:
ECHO %pathToPar2% c -s204800 -r10 -- "%~dp3%~n1%~x3"
ECHO ________________________________________________________________________
ECHO.
REM =================================
REM  Create Par2 files with PAR2.EXE
REM =================================
%pathToPar2% c -s204800 -r10 -- "%~dp3%~n1%~x3"

GOTO:EOF

:WaitForApeFile
REM: Pause for two seconds before returning
ECHO.
ECHO Waiting for "%~dp3%~n1%~x3" to be created...
PING 1.1.1.1 -n 1 -w 2000 >NUL
GOTO ApeFileCheck

Back to the guide | View eac-enc.bat