CD Backup

eac-enc.bat

@ECHO OFF
CLS

REM EAC-ENC.BAT Written by Neil Popham, 2004 (neilpopham@bigfoot.com)

SET version=2.0.11

TITLE=EAC-ENC.BAT, Version %version%

REM ===================
REM  Parameter mapping
REM ===================
REM  %o  %s  %d  "%a"  "%g"  %hHIGH%h  %lLOW%l DISCNO
REM  %1  %2  %3   %4    %5   %6        %6      %7

REM ######################################################
REM  PLEASE EDIT THE PATHS TO THE NECESSARY APPLICATIONS
REM =====================================================
SET pathToMac="C:\DOS\MAC.EXE"
SET pathToTag="C:\DOS\TAG.EXE"
SET pathToPar2="C:\DOS\PAR2.EXE"
REM =====================================================
REM  PLEASE EDIT THE PATHS TO THE STORAGE FOLDERS 
REM  NB: if you paths below contain spaces do *not*
REM      surround the path in quotes
REM =====================================================
SET apeFolder=E:\CDBackup\APE
SET csvLogFolder=E:\CDBackup\Log
REM =====================================================
REM  YOU DO NOT NEED TO EDIT ANY TEXT BELOW, OR IN 
REM  EAC-POST.BAT. HOWEVER, YOU MAY DO SO IF YOU WISH
REM ######################################################

REM ==================
REM  Create Variables 
REM ==================
REM Path to eac-enc's log file
SET eacEncLog=%~dp3eac-enc.log
REM ==================================================================================
REM  Create folder/file names, replacing illegal characters with a space (as per EAC)
REM ==================================================================================
REM EAC Log file
CALL :MakePath "%~5.log" logFilename
REM Artist folder
CALL :MakePath %4 artistFolder
REM Album folder
CALL :MakePath %5 albumFolder

REM ===========================
REM  Write variables to screen 
REM ===========================
ECHO Original    (o) : %1
ECHO Source      (s) : %2
ECHO Destination (d) : %3
ECHO CD Artist   (a) : %4
ECHO CD Title    (g) : %5
ECHO.
ECHO MAC.EXE         : %pathToMac%
ECHO TAG.EXE         : %pathToTag%
ECHO PAR2.EXE        : %pathToPar2%
ECHO.
ECHO APE Folder      : %apeFolder%
ECHO CSV Log Folder  : %csvLogFolder%
ECHO.
ECHO Log file        : "%logFilename%"
ECHO Artist folder   : "%artistFolder%"
ECHO Album folder    : "%albumFolder%"

REM ========================
REM  Write variables to log 
REM ========================
ECHO EAC-ENC.BAT, Version %version%> %eacEncLog%
ECHO Written by Neil Popham, 2004 (neilpopham@bigfoot.com)>> %eacEncLog%
ECHO =====================================================>> %eacEncLog%
ECHO.>> %eacEncLog%
ECHO Original    (o) : %1>> %eacEncLog%
ECHO Source      (s) : %2>> %eacEncLog%
ECHO Destination (d) : %3>> %eacEncLog%
ECHO CD Artist   (a) : %4>> %eacEncLog%
ECHO CD Title    (g) : %5>> %eacEncLog%
ECHO.>> %eacEncLog%
ECHO MAC.EXE         : %pathToMac%>> %eacEncLog%
ECHO TAG.EXE         : %pathToTag%>> %eacEncLog%
ECHO PAR2.EXE        : %pathToPar2%>> %eacEncLog%
ECHO.>> %eacEncLog%
ECHO APE Folder      : %apeFolder%>> %eacEncLog%
ECHO CSV Log Folder  : %csvLogFolder%>> %eacEncLog%
ECHO.>> %eacEncLog%
ECHO Log file        : "%logFilename%">> %eacEncLog%
ECHO Artist folder   : "%artistFolder%">> %eacEncLog%
ECHO Album folder    : "%albumFolder%">> %eacEncLog%

REM =======================
REM  Set compression level
REM =======================
ECHO.
IF "%6"=="LOW" CALL :SetLow
IF "%6"=="HIGH" CALL :SetHigh

REM ================================
REM  Encode wave file using MAC.EXE
REM ================================
SET macCommand=%pathToMac% %2 %3 -C%macCompression%
ECHO.
ECHO CALLING MAC USING THE FOLLOWING COMMAND:
ECHO %macCommand%
ECHO ________________________________________________________________________
ECHO.
ECHO.>> %eacEncLog%
ECHO CALLING MAC USING THE FOLLOWING COMMAND:>> %eacEncLog%
ECHO %macCommand%>> %eacEncLog%
ECHO ________________________________________________________________________>> %eacEncLog%
ECHO.>> %eacEncLog%
%macCommand%

REM ===============================
REM  Open post-encoding batch file
REM ===============================
CD "%~dp0"
START CMD.EXE /c eac-post.bat %1 %2 %3 %4 %5 %6 %7

REM =====
REM  END
REM =====
GOTO:EOF

REM ==========================================
REM  SetLow : sets compression rate to normal
REM ==========================================
:SetLow
REM Compression level: Normal
ECHO Compression     : Normal
ECHO Compression     : Normal>> %eacEncLog%
SET macCompression=2000
GOTO:EOF

REM =========================================
REM  SetHigh : sets compression rate to high
REM =========================================
:SetHigh
REM Compression level: Extra High
ECHO Compression     : Extra High
ECHO Compression     : Extra High>> %eacEncLog%
SET macCompression=4000
GOTO:EOF

REM ============================================================
REM  MakePath : turns a string into a valid folder or file name
REM           : %1 The string to convert
REM           : %2 The name of the variable to return
REM ============================================================
:MakePath
SET tmpString=%1
SET tmpString=%tmpString:/= %
SET tmpString=%tmpString:\= %
SET tmpString=%tmpString::= %
SET tmpString=%tmpString:?= %
SET tmpString=%tmpString:<= %
SET tmpString=%tmpString:>= %
SET tmpString=%tmpString:|= %
REM Now remove asterisks...
SET tmpString=%tmpString: =/%
SET tmpString=%tmpString:,=\%
SET tmpString=%tmpString:&=¬%
SET tmpString=%tmpString:"=%
SET output=
SET /A counter=-1
:MakePathNextChar
SET /A counter+=1
CALL :EXEC SET char=%%tmpString:~%counter%,1%%%
if NOT DEFINED char GOTO :MakePathDone
if [%char%] EQU [*] SET char=/
SET output=%output%%char%
GOTO :MakePathNextChar
:MakePathDone
SET output=%output:/= %
SET output=%output:\=,%
SET %2=%output:¬=^&%
GOTO:EOF
:EXEC
%*
GOTO:EOF

Back to the guide | View eac-post.bat